esta rutina llamada fhd convierte los elementos seleccionados en base a la escala seleccionada para que tengan la impresion de que han sido dibujados a mano.
el overlap se refiere al tamaño del traslape de lineas y el wiggle se refiere a la sinuosidad de las lineas, espero les sea de utilidad, muchas gracias.
quiero aclarar que esta rutina no es de mi autoria, pero igual espero sea de su utilidad

(defun c:FHD (/ *fh:err* o_m c_e fh_s fh_os fh_ws
x ss ssp e ed llc p1 p2
d el ne vertno ang vertd offd offang
vlst elst lp dsf
)
;-ERROR HANDLING
(defun *fh:err* (m)
(or
(member m
'("Function cancelled" "quit / exit abort" "console break")
)
(prompt (strcat "\n< " m " >\n"))
)
(setvar "osmode" o_m)
(setvar "cmdecho" c_e)
(setq *error* *e*)
(princ)
)

;-GET VALUES/SETUP
(setq *e* (cond (*e*)
(*error*)
)
*error* *fh:err*
c_e (getvar "cmdecho")
o_m (getvar "osmode")
dsf (getvar "dimscale") ;TSC (scale)
)
(setvar "cmdecho" 0)
(command "undo" "e" "undo" "g")
(setvar "osmode" 0)
(or (= (type fh_scl) 'REAL) (setq fh_scl 1.0))
(or (= (type fh_oscl) 'INT) (setq fh_oscl 3))
(or (= (type fh_wscl) 'INT) (setq fh_wscl 3))

;-GET FREEHAND SCALE FACTOR
(if (setq fh_s
(getreal (strcat "\nFreehand Scale <" (rtos fh_scl 2) ">: ")
)
)
(setq fh_scl fh_s)
)

;-GET AMOUNT OF OVERLAP
(initget "0 1 2 3 4 5")
(if (setq fh_os
(getint
(strcat "\nLine OVERLAP amount [1 small-5 large, 0 none] <"
(itoa fh_oscl)
">: "
)
)
)
(setq fh_oscl fh_os)
)
(cond ((= fh_oscl 0) (setq fh_os nil))
((= fh_oscl 1) (setq fh_os 0.2))
((= fh_oscl 2) (setq fh_os 0.7))
((= fh_oscl 3) (setq fh_os 1.2))
((= fh_oscl 4) (setq fh_os 1.7))
((= fh_oscl 5) (setq fh_os 2.2))
)

(initget "0 1 2 3 4 5")

;-GET AMOUNT OF WIGGLE
(if (setq fh_ws
(getint
(strcat "\nLine WIGGLE amount [1 small-5 large, 0 none] <"
(itoa fh_wscl)
">: "
)
)
)
(setq fh_wscl fh_ws)
)
(cond ((= fh_wscl 0) (setq fh_ws nil))
((= fh_wscl 1) (setq fh_ws 0.02))
((= fh_wscl 2) (setq fh_ws 0.07))
((= fh_wscl 3) (setq fh_ws 0.12))
((= fh_wscl 4) (setq fh_ws 0.17))
((= fh_wscl 5) (setq fh_ws 0.22))
)

;-SELECT OBJECTS
(if (setq ss (ssget '((-4 . "<OR")
(0 . "LINE")
(0 . "LWPOLYLINE")
(0 . "POLYLINE")
(-4 . "OR>")
)
)
)
(progn
(prompt "\nFREEHAND in progress...")
(if (setq

ssp (ssget "P" '((-4 . "<NOT") (0 . "LINE") (-4 . "NOT>")))
)
(progn
(setq el (entlast)
x 0
)
(while (setq ne el
el (entnext el)
)
)
(while (< x (sslength ssp))
(ssdel (setq e (ssname ssp x)) ss)
(command ".explode" e)
(setq x (1+ x))
)
(while (setq ne (entnext ne)) (ssadd ne ss))
)
)
(setq x 0)
(while (< x (sslength ss))
(setq e (ssname ss x)
ed (entget e)
)
;-GET NEEDED INFO FROM LINE
(setq llc (list (assoc 8 ed)) ;start Layer/Ltype/Color list
p1 (cdr (assoc 10 ed))
p2 (cdr (assoc 11 ed))
ang (angle p1 p2)
d (distance p1 p2)
)
(if (assoc 6 ed)
(setq llc (cons (assoc 6 ed) llc))
)
(if (assoc 62 ed)
(setq llc (cons (assoc 62 ed) llc))
)
;-CREATE OVERLAP
(if (and fh_os (> d 0))
(progn
;*-overlap distance, adjust # after "dsf" - larger=less
(setq ovlpd (+ (* (/ dsf 160) fh_scl) (* fh_os fh_scl))
p1 (polar p1 ang (- ovlpd))
p2 (polar p2 ang ovlpd)
)
(setq ed (subst (cons 10 p1) (assoc 10 ed) ed)
ed (subst (cons 11 p2) (assoc 11 ed) ed)
)
(entmod ed)
(setq d (distance p1 p2))
)
)
;-CREATE WIGGLE
(if (and fh_ws (> d 0))
(progn
(setq vlst nil
lp p1
;*-number of vertices, adjust # after "dsf" -larger=more
vertno (fix (/ d (+ (* (/ dsf 16) fh_scl) (* 3 fh_scl))))
;;;(+ (* (/ dsf 16) fh_scl) 3)))
vertd (if (> vertno 0)
(/ d (1+ vertno))
)
;*-offset distance for vertices, adjust # after "dsf" -larger=less
offd (+ (* (/ dsf 480) fh_scl) (* fh_ws fh_scl))
offang (+ ang (/ pi 2))
)
;-MAKE LIST OF VERTICES FOR NEW PLINE
(repeat vertno
(setq lp (polar lp ang vertd)

vlst (cons (polar lp offang offd) vlst)
offang (+ offang pi)
)
)
;-DELETE LINE
(entdel e)
(setq e nil)
(if (= (substr (getvar "acadver") 1 2) "14")
(progn
(setq elst (list (cons 10 p2)
'(40 . 0.0)
'(41 . 0.0)
'(42 . 0.0)
)
)
(foreach v vlst
(setq elst (append (list (cons 10 v)
'(40 . 0.0)
'(41 . 0.0)
'(42 . 0.0)
)
elst
)
)
)
(setq elst (append (list (cons 10 p1)
'(40 . 0.0)
'(41 . 0.0)
'(42 . 0.0)
)
elst
)
)
(entmake
(append '((0 . "LWPOLYLINE") (100 . "AcDbEntity"))
llc
(list '(100 . "AcDbPolyline")
(cons 90 (/ (length elst) 4))
'(70 . 0)
)
elst
)
)
)
(progn
;-REPLACE WITH PLINE
(entmake
(append '((0 . "POLYLINE") (70 . 128) (66 . 1)) llc)
)
(entmake (append (list '(0 . "VERTEX") (cons 10 p2)) llc)
)
(foreach n vlst
(entmake
(append (list '(0 . "VERTEX") (cons 10 n)) llc)
)
)
(entmake (append (list '(0 . "VERTEX") (cons 10 p1)) llc)
)
(entmake (cons '(0 . "SEQEND") llc))
)
)
)
)
(setq x (1+ x))
)
(command "undo" "e")
(prompt "\nFreehand complete. ")
)
)

;-RETURN VALUES
(setvar "osmode" o_m)
(setvar "cmdecho" c_e)
(setq *error* *e*)
(princ)
)
;-END FILE

muy bueno gracias...

Podrias subir una captura para ver el resultado final?

Gracias

__________________

WTF???... No entendí absolutamente nada.. Si se trata de una lengua muerta o algo. no se.. ¿Alguien me explica?

__________________

portFOLIO: http://3d-space.blogspot.com/

es lo que pense pues suena muy interesante

__________________

Parece ser que el tema ya es viejo... Pero si se escucha interesante...

en donde iserto esa rutina? es para Autocad? Suena fantastica... alguien la ha probado?

__________________

www.tallerveinticuatro.blogspot.com

no tengo idea como ? pero seria genial saber

si es lo que creo, es una rutina para CAD; en donde se configuran las lineas para que parezcan que fueron trazados a mano alzada, se va definiendo llamemosle burdamente "la soltura de la mano" osea que tan movida sale la linea, también se configuran las distancias que uno desea para hacer los cruces de lineas.; en verdad muy buena rutina. (si es la que creo que es )
y con respecto a algo similar, hay un soft de autodesk que se llama autodesk impression , para dar a las presentaciones efectos de lapiz, plumón (marcador) o acauarela chequen este VIDEO

Es justamente lo que habia entendido Raul!
Estaria bueno que alguien pruebe este rutina y suba el resultado para ver como queda

__________________

jaja me extraña.... copien la rutina a un editor de texto.. (notepad o similar) en guardar como pongan el nombre que quieran y la extension .lsp, guarden en un lugar sencillo y carguenla normalmente con autocad... el comando segun la rutina es FHD... lo haria, pero ahora no estoy trabajando con cad :P

__________________

uh yo tengo una pero en la ofi, y estamos de licencia hasta el 2 de agosto, tendran que esperar
esa rutina extendia los bordes de las lineas unos 2mm (se configuraba) y "ondeaba" la linea par que parezca a mano...
.
-------------------------------------------------------------------------------------
.
Sip, es la misma que tenia yo, me tome el atrevimiento de traducirla.

1- No spide la escala, es totalmente arbitraria, de 1 a 5 (se puede modificar facilmente la rutina ara agregarle mas escalas, si la estudias te daras cuenta lo simple que es)

2- Nos pide si queremos que las lineas se extiendan en las esquinas, de 1 a 5, 0 si no queremos esta opcion

3- Nos pide si queremos que las lineas se ondulen simulando un pulso tembleque...de 1 a 5, 0 si no queremos esta opcion

Como dijo el amigo grafio, la descargan, la descomprimen en su carpeta favorita, y la cargan con APPLOAD y FHD para correrla

Les dejo unas muestras muuuuy simples:

Archivos Adjuntos

freehand.rar (1.7 KB (Kilobytes), 67 visitas)

__________________

xxxx el que lee

Perdon el off topic pero....Lean, les dieron licencia???? wow!

__________________
"Life is like a box of chocolates; you never know what you're gonna get."
www.carlaale.com.ar

Iniciado por Carli

Perdon el off topic pero....Lean, les dieron licencia???? wow!

A todos los estatales provinciales con hijos menores de 14 años, ademas fallecio un compañero de la division dibujo, a dos ofis de la mia, aun no estan los resultados pero murio de neumonia..., en la consultora por supuesto que no porque es privada, se ve que ahi no me contagiare no se...jeje

__________________

xxxx el que lee

Joder!!!!! esto va de mal en peor.... fin

__________________
"Life is like a box of chocolates; you never know what you're gonna get."
www.carlaale.com.ar